source: contrib/MailArchiver/sources/vendor/mime4j/custom/dom/src/main/javacc/org/apache/james/mime4j/field/datetime/DateTimeParser.jj @ 6785

/****************************************************************
 * Licensed to the Apache Software Foundation (ASF) under one   *
 * or more contributor license agreements.  See the NOTICE file *
 * distributed with this work for additional information        *
 * regarding copyright ownership.  The ASF licenses this file   *
 * to you under the Apache License, Version 2.0 (the            *
 * "License"); you may not use this file except in compliance   *
 * with the License.  You may obtain a copy of the License at   *
 *                                                              *
 *   http://www.apache.org/licenses/LICENSE-2.0                 *
 *                                                              *
 * Unless required by applicable law or agreed to in writing,   *
 * software distributed under the License is distributed on an  *
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY       *
 * KIND, either express or implied.  See the License for the    *
 * specific language governing permissions and limitations      *
 * under the License.                                           *
 ****************************************************************/


/**
 * RFC2822 date parser.
 *
 * Created 9/28/2004
 * by Joe Cheng <code@joecheng.com>
 */

options {
        STATIC=false;
        LOOKAHEAD=1;
        IGNORE_CASE=true;
        JDK_VERSION = "1.5";
        OUTPUT_DIRECTORY = "../../../../../../../../../target/generated-sources/javacc";
        //DEBUG_PARSER=true;
        //DEBUG_TOKEN_MANAGER=true;
}

PARSER_BEGIN(DateTimeParser)
/****************************************************************
 * Licensed to the Apache Software Foundation (ASF) under one   *
 * or more contributor license agreements.  See the NOTICE file *
 * distributed with this work for additional information        *
 * regarding copyright ownership.  The ASF licenses this file   *
 * to you under the Apache License, Version 2.0 (the            *
 * "License"); you may not use this file except in compliance   *
 * with the License.  You may obtain a copy of the License at   *
 *                                                              *
 *   http://www.apache.org/licenses/LICENSE-2.0                 *
 *                                                              *
 * Unless required by applicable law or agreed to in writing,   *
 * software distributed under the License is distributed on an  *
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY       *
 * KIND, either express or implied.  See the License for the    *
 * specific language governing permissions and limitations      *
 * under the License.                                           *
 ****************************************************************/
package org.apache.james.mime4j.field.datetime.parser;

import org.apache.james.mime4j.dom.datetime.DateTime;

public class DateTimeParser {
    private static final boolean ignoreMilitaryZoneOffset = true;

    public static void main(String args[]) throws ParseException {
                while (true) {
                    try {
                                DateTimeParser parser = new DateTimeParser(System.in);
                        parser.parseLine();
                    } catch (Exception x) {
                                x.printStackTrace();
                                return;
                    }
                }
    }

    private static int parseDigits(Token token) {
        return Integer.parseInt(token.image, 10);
    }

    private static int getMilitaryZoneOffset(char c) {
        if (ignoreMilitaryZoneOffset)
            return 0;

        c = Character.toUpperCase(c);

        switch (c) {
            case 'A': return 1;
            case 'B': return 2;
            case 'C': return 3;
            case 'D': return 4;
            case 'E': return 5;
            case 'F': return 6;
            case 'G': return 7;
            case 'H': return 8;
            case 'I': return 9;
            case 'K': return 10;
            case 'L': return 11;
            case 'M': return 12;

            case 'N': return -1;
            case 'O': return -2;
            case 'P': return -3;
            case 'Q': return -4;
            case 'R': return -5;
            case 'S': return -6;
            case 'T': return -7;
            case 'U': return -8;
            case 'V': return -9;
            case 'W': return -10;
            case 'X': return -11;
            case 'Y': return -12;

            case 'Z': return 0;
            default: return 0;
        }
    }
}

PARSER_END(DateTimeParser)

DateTime parseLine() :
{DateTime dt;}
{
        dt=date_time() ["\r"] "\n"
        { return dt; }
}

DateTime parseAll() :
{DateTime dt;}
{
        dt=date_time() <EOF>
        { return dt; }
}

DateTime date_time() :
{String y; int m, d, h, m2, s=0, z;}
{
(       LOOKAHEAD(2)
        [ day_of_week() "," ] d=day() [<MINUS>] m=month() [<MINUS>] y=year() h=hour() ":" m2=minute() [ ":" s=second() ] z=zone()
|
        m=month() d=day() h=hour() ":" m2=minute() [ ":" s=second() ] y=year() z=zone()
|
        day_of_week() m=month() d=day() h=hour() ":" m2=minute() [ ":" s=second() ] z=zone() y=year()
)
        {
            return new DateTime(y, m, d, h, m2, s, z);
        }
}

String day_of_week() :
{}
{
(   "Domingo" | "Dom" | "Sunday" | "Sun"
|   "Segunda" | "Seg" | "Monday" | "Mon" | "Lunes" | "Lun"
|   "Terça" | "Terca" | "Ter" | "Tuesday" | "Tue" | "Marte" | "Mar"
|   "Quarta" | "Qua" | "Wednesday" | "Wed" | "Miércoles" | "Miercoles" | "Mie"
|   "Quinta" | "Qui" | "Thursday" | "Thu" | "Jueves" | "Jue"
|   "Sexta" | "Sex" | "Friday" | "Fri" | "Viernes" | "Vie"
|   "Sábado" | "Sabado" | "Sáb" | "Sab" | "Saturday" | "Sat"
)
    { return token.image; }
}

int day() :
{Token t;}
{
    t=<DIGITS> { return parseDigits(t); }
}

int month() :
{}
{
    "Janeiro"    { return  1; }
|   "Jan"        { return  1; }
|   "January"    { return  1; }
|   "Enero"      { return  1; }
|   "Ene"        { return  1; }
|   "Fevereiro"  { return  2; }
|   "Fev"        { return  2; }
|   "February"   { return  2; }
|   "Feb"        { return  2; }
|   "Febrero"    { return  2; }
|   "Março"      { return  3; }
|   "Marco"      { return  3; }
|   "Mar"        { return  3; }
|   "March"      { return  3; }
|   "Marzo"      { return  3; }
|   "Abril"      { return  4; }
|   "Abr"        { return  4; }
|   "April"      { return  4; }
|   "Apr"        { return  4; }
|   "Maio"       { return  5; }
|   "Mai"        { return  5; }
|   "May"        { return  5; }
|   "Mayo"       { return  5; }
|   "Junho"      { return  6; }
|   "Jun"        { return  6; }
|   "June"       { return  6; }
|   "Junio"      { return  6; }
|   "Julho"      { return  7; }
|   "Jul"        { return  7; }
|   "July"       { return  7; }
|   "Julio"      { return  7; }
|   "Agosto"     { return  8; }
|   "Ago"        { return  8; }
|   "August"     { return  8; }
|   "Aug"        { return  8; }
|   "Setembro"   { return  9; }
|   "Set"        { return  9; }
|   "September"  { return  9; }
|   "Sep"        { return  9; }
|   "Septiembre" { return  9; }
|   "Outubro"    { return 10; }
|   "Out"        { return 10; }
|   "October"    { return 10; }
|   "Oct"        { return 10; }
|   "Octubre"    { return 10; }
|   "Novembro"   { return 11; }
|   "Nov"        { return 11; }
|   "November"   { return 11; }
|   "Noviembre"  { return 11; }
|   "Dezembro"   { return 12; }
|   "Dez"        { return 12; }
|   "December"   { return 12; }
|   "Dec"        { return 12; }
|   "Diciembre"  { return 12; }
|   "Dic"        { return 12; }
}

String year() :
{Token t;}
{
    t=<DIGITS> { return t.image; }
}

int hour() :
{Token t;}
{
    t=<DIGITS> { return parseDigits(t); }
}

int minute() :
{Token t;}
{
    t=<DIGITS> { return parseDigits(t); }
}

int second() :
{Token t;}
{
    t=<DIGITS> { return parseDigits(t); }
}

int zone() :
{Token u; int z; boolean neg=false; }
{
(   ( <PLUS> | <MINUS> {neg=true;} ) u=<DIGITS> { z=parseDigits(u); if(neg) z*=(-1); }
|   z=obs_zone()
)+
    { return z; }
}

int obs_zone() :
{Token t; int z;}
{
(
// Dateline (Eniwetok, Kwajalein)
    "ZW12" { z = -1200; }

// Samoa
|   "SST"  { z = -1100; }

// Hawaii
|   "BST"  { z = -1000; }

// Alaskan
|   "YST"  { z =  -900; }
|   "YDT"  { z =  -800; }

// Pacific Time (US & Canada, Tijuana)
|   "PST"  { z =  -800; }
|   "PDT"  { z =  -700; }

// Mountain Time (US & Canada)
// US Mountain (Arizona)
|   "MST"  { z =  -700; }
|   "MDT"  { z =  -600; }

// Canada Central (Saskatchewan)
// Central Time (US & Canada)
// Mexico (Mexico City)
// Central America
|   "CST"  { z =  -600; }
|   "CDT"  { z =  -500; }

// Eastern (US & Canada)
// US Eastern (Indiana (East))
// SA Pacific (Bogota, Lima, Quito)
|   "EST"  { z =  -500; }
|   "EDT"  { z =  -400; }

// Atlantic (Canada)
// Pacific SA (Santiago)
// SA Western (Caracas, La Paz)
|   "AST"  { z =  -400; }
|   "ADT"  { z =  -300; }

// Newfoundland
|   "NST" { z =  -330; }
|   "NDT" { z =  -230; }

// SA Eastern Standard Time (Brasilia, Buenos Aires, Georgetown)
// Greenland Standard Time (Greenland)
|   "ZW3"  { z =  -300; }
|   "BRT"  { z =  -300; }

// Mid-Atlantic
|   "ZW2"  { z =  -200; }
|   "YW2"  { z =  -200; }

// Azores, Cape Verde
|   "ZW1"  { z =  -100; }
|   "YW1"  { z =  -100; }

// GMT (Greenwich Mean Time)
// (Dublin, Edinburgh, Lisbon, London, Casablanca, Monrovia)
|   "GMT"  { z =   0; }
|   "GDT"  { z =   0; }
|   "UT"   { z =   0; }

// Central Europe (Belgrade, Bratislava, Budapest, Ljubljana,
// Prague, Sarajevo, Skopje, Sofija, Vilnius, Warsaw, Zagreb)
// Romance (Brussels, Copenhagen, Madrid, Paris)
// West Central Africa
// West Europe Standard Time (Amsterdam, Berlin, Bern, Rome, Stockholm, Vienna)
|   "CET"  { z =   100; }
|   "CEDT" { z =   200; }

// Eastern Europe (Bucharest)
// Egypt (Cairo)
// FLE (Helsinki, Riga, Tallinn)
// GTB (Athens, Istanbul, Minsk)
// Jerusalem
// South Africa (Harare, Pretoria)
|   "ZE2"  { z =   200; }

// Arabic (Kuwait, Riyadh, Baghdad)
// Eastern Africa (Nairobi)
// Russian (Moscow, St. Petersburg, Volgograd)
|   "ZE3"  { z =   300; }

// Iran (Tehran)
|   "ZE3B" { z =   330; }

// Arabian (Abu Dhabi, Muscat)
// Caucasus (Baku, Tbilisi, Yerevan)
|   "ZE4"  { z =   400; }

// Afghanistan (Kabul)
|   "ZE4B" { z =   430; }

// Ekaterinburg
// West Asia (Islamabad, Karachi, Tashkent)
|   "ZE5"  { z =   500; }

// India Standard Time (Calcutta, Chennai, Mumbai, New Delhi)
|   "ZE5B"  { z =   530; }

// Nepal (Kathmandu)
|   "ZE5C"  { z =   545; }

// Central Asia (Astana, Dhaka, Almaty, Novosibirsk)
// Sri Lanka (Sri Jayawardenepura)
|   "ZE6"  { z =   600; }

// Myanmar (Rangoon)
|   "ZE6B"  { z =   630; }

// Asia (Krasnoyarsk Bangkok, Hanoi, Jakarta)
|   "ZE7"  { z =   700; }

// China (Beijing, Chongqing, Hong Kong, Urumqi)
// North Asia East (Irkutsk, Ulaan Bataar)
// Malay Peninsula (Kuala Lumpur, Singapore)
// Taipei
// Western Australia (Perth)
|   "ZE8"  { z =   800; }

// Korea (Seoul)
// Japan (Osaka, Sapporo, Tokyo)
// Yakutsk
|   "ZE9"  { z =   900; }

// Central Australia (Adelaide, Darwin)
|   "ZE9B"  { z =  930; }

// Eastern Australia (Canberra, Melbourne, Sydney, Brisbane)
// Tasmania (Hobart)
// Vladivostok
// West Pacific (Guam, Port Moresby)
|   "ZE10" { z =  1000; }

// Central Pacific (Magadan, Solomon Is., New Caledonia)
|   "ZE11" { z =  1100; }

// Fiji, Kamchatka, Marshall Is.
// New Zealand (Auckland, Wellington)
|   "ZE12" { z =  1200; }

// Tonga (Nuku'alofa)
|   "ZE13" { z =  1300; }

|   t=< MILITARY_ZONE: ["A"-"I","a"-"i","K"-"Z","k"-"z"] > { z=getMilitaryZoneOffset(t.image.charAt(0)); }
)
    { return z; }
}

SPECIAL_TOKEN :
{
        < WS: ( [" ", "\t"] )+ >
}

TOKEN_MGR_DECLS :
{
        // Keeps track of how many levels of comment nesting
        // we've encountered.  This is only used when the 2nd
        // level is reached, for example ((this)), not (this).
        // This is because the outermost level must be treated
        // specially anyway, because the outermost ")" has a
        // different token type than inner ")" instances.
        static int commentNest;
}

MORE :
{
        // starts a comment
        "(" : INCOMMENT
}

<INCOMMENT>
SKIP :
{
        // ends a comment
        < COMMENT: ")" > : DEFAULT
        // if this is ever changed to not be a SKIP, need
        // to make sure matchedToken.token = token.toString()
        // is called.
}

<INCOMMENT>
MORE :
{
        < <QUOTEDPAIR>> { image.deleteCharAt(image.length() - 2); }
|       "(" { commentNest = 1; } : NESTED_COMMENT
|       < <ANY>>
}

<NESTED_COMMENT>
MORE :
{
        < <QUOTEDPAIR>> { image.deleteCharAt(image.length() - 2); }
|       "(" { ++commentNest; }
|       ")" { --commentNest; if (commentNest == 0) SwitchTo(INCOMMENT); }
|       < <ANY>>
}

TOKEN :
{
    < DIGITS: ( ["0"-"9"] )+ >
|   < PLUS: "+" >
|   < MINUS: "-" >
}

// GLOBALS

<*>
TOKEN :
{
        < #QUOTEDPAIR: "\\" <ANY> >
|       < #ANY: ~[] >
}